EasyXLS

How to format Excel cells in Classic ASP

EasyXLS Excel library can be used to export Excel files in Classic ASP. The library is a COM+ component that works without MS Excel installed.

Step 1: Download and install EasyXLS Excel Library for COM+

To download the trial version of EasyXLS Excel Library, press the below button:

Download EasyXLS™ Excel Library for Classic ASP

If you already own a license key, you may login and download EasyXLS from your account.

Step 2: Verify if EasyXLS is registered

Check if EasyXLS component is present in Component Services.

Step 3: Run ASP code that formats Excel file

Execute the following ASP code that formats Excel cells, rows, columns and cell ranges.

<%@ Language=VBScript %>

<!-- #INCLUDE FILE="Alignment.inc" -->
<!-- #INCLUDE FILE="Border.inc" -->
<!-- #INCLUDE FILE="DataType.inc" -->
<!-- #INCLUDE FILE="Color.inc" -->

<%
'===========================================================================
' Tutorial 05
'
' This code sample shows how to export data to Excel file in Classic ASP and
' format the cells. The Excel file has multiple worksheets.
' The first sheet is filled with data and the cells are formatted.
'===========================================================================

response.write("Tutorial 05<br>")
response.write("----------<br>")

' Create an instance of the class that exports Excel files
Set workbook = Server.CreateObject("EasyXLS.ExcelDocument")

' Create two sheets
workbook.easy_addWorksheet_2("First tab")
workbook.easy_addWorksheet_2("Second tab")

' Get the table of data for the first worksheet
Set xlsFirstTable = workbook.easy_getSheetAt(0).easy_getExcelTable()

' Create the formatting style for the header
Set xlsStyleHeader = Server.CreateObject("EasyXLS.ExcelStyle")
xlsStyleHeader.setFont("Verdana")
xlsStyleHeader.setFontSize(8)
xlsStyleHeader.setItalic(True)
xlsStyleHeader.setBold(True)
xlsStyleHeader.setForeground(CLng(COLOR_YELLOW))
xlsStyleHeader.setBackground(CLng(COLOR_BLACK))
xlsStyleHeader.setBorderColors CLng(COLOR_GRAY), CLng(COLOR_GRAY), CLng(COLOR_GRAY), CLng(COLOR_GRAY)
xlsStyleHeader.setBorderStyles BORDER_BORDER_MEDIUM, BORDER_BORDER_MEDIUM, _
                                    BORDER_BORDER_MEDIUM, BORDER_BORDER_MEDIUM
xlsStyleHeader.setHorizontalAlignment(ALIGNMENT_ALIGNMENT_CENTER)
xlsStyleHeader.setVerticalAlignment(ALIGNMENT_ALIGNMENT_BOTTOM)
xlsStyleHeader.setWrap(True)
xlsStyleHeader.setDataType(DATATYPE_STRING)

' Add data in cells for report header
for column = 0 to 4
xlsFirstTable.easy_getCell(0,column).setValue("Column " & (column + 1))
xlsFirstTable.easy_getCell(0,column).setStyle(xlsStyleHeader)
next
xlsFirstTable.easy_getRowAt(0).setHeight(30)

' Create a formatting style for cells
Set xlsStyleData = Server.CreateObject("EasyXLS.ExcelStyle")
xlsStyleData.setHorizontalAlignment(ALIGNMENT_ALIGNMENT_LEFT)
xlsStyleData.setForeground(CLng(COLOR_DARKGRAY))
xlsStyleData.setWrap(False)
xlsStyleData.setDataType(DATATYPE_STRING)

' Add data in cells for report values
for row = 0 to 99
    for column = 0 to 4
        xlsFirstTable.easy_getCell(row+1,column).setValue("Data " & (row + 1) & ", " & (column + 1))
        xlsFirstTable.easy_getCell(row+1,column).setStyle(xlsStyleData)
    next
next

' Set column widths
xlsFirstTable.setColumnWidth_2 0, 70
xlsFirstTable.setColumnWidth_2 1, 100
xlsFirstTable.setColumnWidth_2 2, 70
xlsFirstTable.setColumnWidth_2 3, 100
xlsFirstTable.setColumnWidth_2 4, 70

' Export the Excel file
response.write("Writing file: C:\Samples\Tutorial05 - format Excel cells.xlsx<br>")
workbook.easy_WriteXLSXFile("C:\Samples\Tutorial05 - format Excel cells.xlsx")

' Confirm export of Excel file
if workbook.easy_getError() = "" then
    response.write("File successfully created.")
else
    response.write("Error encountered: " + workbook.easy_getError())
end if

' Dispose memory
workbook.Dispose
%>

Overloaded methods
For methods with same name but different parameters, only the first method overload retains the original name. Subsequent overloads are uniquely renamed by appending to the method name '_2', '_3', etc (method, method_2, method_3), an integer that corresponds to the order of declaration that can be found in EasyXLS.h, a file that comes with EasyXLS installation.

EasyXLS Excel components:

.NET
Excel Library for Classic ASP
full COM+ version to import, export or convert Excel files
Excel Writer for Classic ASP
COM+ version to create and export Excel files
Download EasyXLS™ Excel Component for Classic ASP

File formats:

MS Excel 97 - 2003
MS Excel 2007 - 2019
MS Excel 2021
Office 365
XLSXXLSMXLSBXLS
XMLHTMLCSVTXT